*DECK MCGSIG
      SUBROUTINE MCGSIG(NMAT,NGEFF,KPSYS,ALBEDO,SIGAL,LVOID)
*
*-----------------------------------------------------------------------
*
*Purpose:
* Construct total cross sections and albedos array and check for void.
*
*Copyright:
* Copyright (C) 2002 Ecole Polytechnique de Montreal
* This library is free software; you can redistribute it and/or
* modify it under the terms of the GNU Lesser General Public
* License as published by the Free Software Foundation; either
* version 2.1 of the License, or (at your option) any later version
*
*Author(s): R. Le Tellier
*
*Parameters: input
* NMAT    number of mixtures.
* NGEFF   effective number of energy groups.
* KPSYS   pointer array for each group properties.
* ALBEDO  albedos array.
*
*Parameters: output
* SIGAL   total cross sections and albedos array.
* LVOID   void flag.
*
*-----------------------------------------------------------------------
*
      USE GANLIB
      IMPLICIT NONE
*---
* SUBROUTINES ARGUMENTS
*---
      INTEGER NMAT,NGEFF
      TYPE(C_PTR) KPSYS(NGEFF)
      REAL ALBEDO(6),SIGAL(-6:NMAT,NGEFF)
      LOGICAL LVOID
*---
* LOCAL VARIABLES
*---
      TYPE(C_PTR) JPSYS
      INTEGER II,I
*
      LVOID=.FALSE.
      DO II=1,NGEFF
         JPSYS=KPSYS(II)
         CALL LCMGET(JPSYS,'DRAGON-TXSC',SIGAL(0,II))
         DO I=1,NMAT
            IF (SIGAL(I,II).EQ.0.0) LVOID=.TRUE.
         ENDDO
         DO I=-6,-1
            SIGAL(I,II)=ALBEDO(-I)
         ENDDO
      ENDDO
*
      RETURN
      END
