*DECK ALLUS
      SUBROUTINE ALLUS(L4,MU1,IMA,ASS,F)
*
*-----------------------------------------------------------------------
*
* SOLUTION OF A LINEAR SYSTEM WHERE THE COEFFICIENT MATRIX HAVE BEEN
* FACTORIZED BY A PRECEDING CALL TO ALLUF.
*
* INPUT PARAMETERS:
*    L4 : ORDER OF THE COEFFICIENT MATRIX.
*   MU1 : POSITION OF EACH DIAGONAL ELEMENT IN VECTOR ASS.
*   IMA : POSITION OF THE FIRST NON-ZERO COLUMN ELEMENT IN VECTOR ASS.
*         DIMENSION MU1(L4),IMA(L4)
*   ASS : LU FACTORS OF THE COEFFICIENT MATRIX IN COMPRESSED DIAGONAL
*         STORAGE MODE. DIMENSION ASS(IMA(L4))
*     F : RIGHT-HAND SIDE OF THE LINEAR SYSTEM. DIMENSION F(L4)
*
* OUTPUT PARAMETER:
*     F : SOLUTION OF THE LINEAR SYSTEM. DIMENSION F(L4)
*
*-------------------------------------- AUTHOR: A. HEBERT ; 15/09/89 ---
*
      DIMENSION MU1(*),IMA(*),ASS(*),F(*)
      F(1)=F(1)/ASS(MU1(1))
      DO 20 I=2,L4
      K1=IMA(I-1)+1
      K2=MU1(I)
      KJ=I-K2+K1
      T=-F(I)
      DO 10 K=K1,K2-1
      T=T+F(KJ)*ASS(K)
   10 KJ=KJ+1
   20 F(I)=-T/ASS(MU1(I))
*
      DO 30 I=L4,2,-1
      K1=IMA(I)
      K2=MU1(I)
      KJ=I-K1+K2
      T=-F(I)
      DO 30 K=K1,K2+1,-1
      F(KJ)=F(KJ)+ASS(K)*T
   30 KJ=KJ+1
      RETURN
      END
