*DECK ALLDLS
      SUBROUTINE ALLDLS (L4,MU1,ASS,F)
*
*-----------------------------------------------------------------------
*
* SOLUTION OF A SYMMETRIC LINEAR SYSTEM WHERE THE COEFFICIENT MATRIX
* HAVE BEEN FACTORIZED BY A PRECEDING CALL TO ALLDLF.
*
* INPUT PARAMETERS:
*    L4 : ORDER OF THE COEFFICIENT MATRIX.
*   MU1 : POSITION OF EACH DIAGONAL ELEMENT IN VECTOR ASS.
*         DIMENSION MU1(L4)
*   ASS : LDL(T) FACTORS OF THE COEFFICIENT MATRIX IN COMPRESSED
*         DIAGONAL STORAGE MODE. DIMENSION ASS(MU1(L4)-MU1(1)+1)
*     F : RIGHT-HAND SIDE OF THE LINEAR SYSTEM. DIMENSION F(L4)
*
* OUTPUT PARAMETER:
*     F : SOLUTION OF THE LINEAR SYSTEM. DIMENSION F(L4)
*
*-------------------------------------- AUTHOR: A. HEBERT ; 15/09/89 ---
*
      DIMENSION ASS(*),MU1(*),F(*)
      IF (L4.EQ.1) GO TO 60
      K1=MU1(1)+1
      DO 20 I=2,L4
      K2=MU1(I)
      KJ=I-K2+K1
      T=-F(I)
      DO 10 K=K1,K2-1
      T=T+F(KJ)*ASS(K)
   10 KJ=KJ+1
      K1=K2+1
   20 F(I)=-T
C
      DO 30 I=1,L4
   30 F(I)=F(I)*ASS(MU1(I))
C
      K2=MU1(L4)
      DO 50 I=L4,2,-1
      T=-F(I)
      K1=MU1(I-1)+1
      KJ=I-K2+K1
      DO 40 K=K1,K2-1
      F(KJ)=F(KJ)+ASS(K)*T
   40 KJ=KJ+1
   50 K2=K1-1
      RETURN
C
   60 F(1)=F(1)*ASS(MU1(1))
      RETURN
      END
